【MQL5】ごく単純なルールで取引するEAを作ってみる

// 上に抜けた
if ((rt[0].open <= ma[0]) && (rt[0].close > ma[0]))
{
    // 注文
    MqlTradeRequest req;
    MqlTradeResult res;
    ZeroMemory(req);
    ZeroMemory(res);

    req.action       = TRADE_ACTION_DEAL;
    req.symbol       = _Symbol;
    req.volume       = Lots;
    req.price        = SymbolInfoDouble(_Symbol, SYMBOL_ASK);
    req.sl           = req.price - StopPoints * _Point;
    req.tp           = req.price + LimitPoints * _Point;
    req.deviation    = AllowableSlipPoints;
    req.type         = ORDER_TYPE_BUY;
    req.type_filling = fillMode;
    req.magic        = magic;

    if (OrderSend(req, res))
    {
        Print(res.comment);

        if (res.retcode != TRADE_RETCODE_DONE)
            PrintFormat("Failed to send an order. [%d] : %s", GetLastError(), res.comment);
        else
            status = 1;
    }
    else
    {
        PrintFormat("Failed to send an order. [%d]", GetLastError());
    }
}
// 下に抜けた
else if ((rt[0].open >= ma[0]) && (rt[0].close < ma[0]))
{
    // 注文
    MqlTradeRequest req;
    MqlTradeResult res;
    ZeroMemory(req);
    ZeroMemory(res);

    req.action       = TRADE_ACTION_DEAL;
    req.symbol       = _Symbol;
    req.volume       = Lots;
    req.price        = SymbolInfoDouble(_Symbol, SYMBOL_BID);
    req.sl           = req.price + StopPoints * _Point;
    req.tp           = req.price - LimitPoints * _Point;
    req.deviation    = AllowableSlipPoints;
    req.type         = ORDER_TYPE_SELL;
    req.type_filling = fillMode;
    req.magic        = magic;

    if (OrderSend(req, res))
    {
        Print(res.comment);

        if (res.retcode != TRADE_RETCODE_DONE)
            PrintFormat("Failed to send an order. [%d] : %s", GetLastError(), res.comment);
        else
            status = 2;
    }
    else
    {
        PrintFormat("Failed to send an order. [%d]", GetLastError());
    }
}

void CheckExit()
{
    if (status == 0)
        return;

    // ローソク足を取得
    MqlRates rt[2];
    if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
    {
        PrintFormat("Failed to get history data. [%d]", GetLastError());
        return;
    }

    // MAを取得
    double ma[2];
    if (CopyBuffer(hMA, 0, 0, 2, ma) != 2)
    {
        PrintFormat("Failed to get MA values. [%d]", GetLastError());
        return;
    }

    // ロングポジション保有中で下抜けた　または
    // ショートポジション保有中で上抜けた
    if (((status == 1) && (rt[0].close < ma[0])) ||
        ((status == 2) && (rt[0].close > ma[0])))
    {
        // 決済
        MqlTradeRequest req;
        MqlTradeResult res;
        ZeroMemory(req);
        ZeroMemory(res);

        req.action       = TRADE_ACTION_DEAL;
        req.position     = PositionGetTicket(0);
        req.symbol       = _Symbol;
        req.volume       = Lots;
        req.deviation    = AllowableSlipPoints;
        req.type         = status == 1 ? ORDER_TYPE_SELL : ORDER_TYPE_BUY;
        req.type_filling = ORDER_FILLING_IOC;
        req.magic        = magic;
        
        if (OrderSend(req, res))
        {
            Print(res.comment);

            if (res.retcode != TRADE_RETCODE_DONE)
                PrintFormat("Failed to send an order. [%d] : %s", GetLastError(), res.comment);
        }
        else
        {
            PrintFormat("Failed to send an order. [%d]", GetLastError());
        }
    }
}

//+------------------------------------------------------------------+
//|                                                      Sample1.mq5 |
//|                                            Copyright 2024, Hailu |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, Hailu"
#property link      "https://www.mql5.com"
#property version   "1.00"

input uint  MaPeriod            = 20;
input uint  Lots                = 1;
input uint  LimitPoints         = 1000;
input uint  StopPoints          = 300;
input ulong AllowableSlipPoints = 20;

int                     hMA = 0;    // MAインジケータのハンドル
int                     status = 0; // 0:未エントリー / 1:ロングポジション保有 / 2:ショートポジション保有
datetime                prevBarDt;  // 1つ前のローソク足の開始時刻
ENUM_ORDER_TYPE_FILLING fillMode;   // 執行条件

const ulong magic = 1;  // このEAのID

//--------------------------------------------------------------------
// 買い・売り条件を満たしていれば注文する
//--------------------------------------------------------------------
void CheckEnter()
{
    // ローソク足を取得
    MqlRates rt[2];
    if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
    {
        PrintFormat("Failed to get history data. [%d]", GetLastError());
        return;
    }

    // MAを取得
    double ma[2];
    if (CopyBuffer(hMA, 0, 0, 2, ma) != 2)
    {
        PrintFormat("Failed to get MA values. [%d]", GetLastError());
        return;
    }

    // 上に抜けた
    if ((rt[0].open <= ma[0]) && (rt[0].close > ma[0]))
    {
        // 注文
        MqlTradeRequest req;
        MqlTradeResult res;
        ZeroMemory(req);
        ZeroMemory(res);

        req.action       = TRADE_ACTION_DEAL;
        req.symbol       = _Symbol;
        req.volume       = Lots;
        req.price        = SymbolInfoDouble(_Symbol, SYMBOL_ASK);
        req.sl           = req.price - StopPoints * _Point;
        req.tp           = req.price + LimitPoints * _Point;
        req.deviation    = AllowableSlipPoints;
        req.type         = ORDER_TYPE_BUY;
        req.type_filling = fillMode;
        req.magic        = magic;


        if (OrderSend(req, res))
        {
            Print(res.comment);

            if (res.retcode != TRADE_RETCODE_DONE)
                PrintFormat("Failed to send an order. [%d] : %s", GetLastError(), res.comment);
            else
                status = 1;
        }
        else
        {
            PrintFormat("Failed to send an order. [%d]", GetLastError());
        }
    }
    // 下に抜けた
    else if ((rt[0].open >= ma[0]) && (rt[0].close < ma[0]))
    {
        // 注文
        MqlTradeRequest req;
        MqlTradeResult res;
        ZeroMemory(req);
        ZeroMemory(res);

        req.action       = TRADE_ACTION_DEAL;
        req.symbol       = _Symbol;
        req.volume       = Lots;
        req.price        = SymbolInfoDouble(_Symbol, SYMBOL_BID);
        req.sl           = req.price + StopPoints * _Point;
        req.tp           = req.price - LimitPoints * _Point;
        req.deviation    = AllowableSlipPoints;
        req.type         = ORDER_TYPE_SELL;
        req.type_filling = fillMode;
        req.magic        = magic;

        if (OrderSend(req, res))
        {
            Print(res.comment);

            if (res.retcode != TRADE_RETCODE_DONE)
                PrintFormat("Failed to send an order. [%d] : %s", GetLastError(), res.comment);
            else
                status = 2;
        }
        else
        {
            PrintFormat("Failed to send an order. [%d]", GetLastError());
        }
    }
}
//--------------------------------------------------------------------
// 決済条件を満たしていれば決済する
//--------------------------------------------------------------------
void CheckExit()
{
    if (status == 0)
        return;

    // ローソク足を取得
    MqlRates rt[2];
    if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
    {
        PrintFormat("Failed to get history data. [%d]", GetLastError());
        return;
    }

    // MAを取得
    double ma[2];
    if (CopyBuffer(hMA, 0, 0, 2, ma) != 2)
    {
        PrintFormat("Failed to get MA values. [%d]", GetLastError());
        return;
    }

    // ロングポジション保有中で下抜けた　または
    // ショートポジション保有中で上抜けた
    if (((status == 1) && (rt[0].close < ma[0])) ||
        ((status == 2) && (rt[0].close > ma[0])))
    {
        // 決済
        MqlTradeRequest req;
        MqlTradeResult res;
        ZeroMemory(req);
        ZeroMemory(res);

        req.action       = TRADE_ACTION_DEAL;
        req.position     = PositionGetTicket(0);
        req.symbol       = _Symbol;
        req.volume       = Lots;
        req.deviation    = AllowableSlipPoints;
        req.type         = status == 1 ? ORDER_TYPE_SELL : ORDER_TYPE_BUY;
        req.type_filling = fillMode;
        req.magic        = magic;
        
        if (OrderSend(req, res))
        {
            Print(res.comment);

            if (res.retcode != TRADE_RETCODE_DONE)
                PrintFormat("Failed to send an order. [%d] : %s", GetLastError(), res.comment);
        }
        else
        {
            PrintFormat("Failed to send an order. [%d]", GetLastError());
        }
    }
}
//--------------------------------------------------------------------
// 執行条件を選択
//--------------------------------------------------------------------
void SelectFillType()
{
    long fm = SymbolInfoInteger(_Symbol, SYMBOL_FILLING_MODE);

    if ((fm & SYMBOL_FILLING_FOK) != 0)
        fillMode = ORDER_FILLING_FOK;
    else
        fillMode = ORDER_FILLING_IOC;

    PrintFormat("Filling mode = %d", fillMode);
}

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
{
    // 執行条件を選択
    SelectFillType();

    // MAインジケータを作成
    hMA = iMA(_Symbol, _Period, MaPeriod, 0, MODE_SMA, PRICE_CLOSE);
    if (hMA == INVALID_HANDLE)
    {
        PrintFormat("Failed to create MA indicators. [%d]", GetLastError());
        return INIT_FAILED;
    }

    // 1つ前のローソク足の時刻を初期化
    prevBarDt = iTime(_Symbol, _Period, 0);

    return INIT_SUCCEEDED;
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
//---
   
}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
{
    // 現在のローソク足の開始時刻を取得
    datetime dt = iTime(_Symbol, _Period, 0);
    if (dt == 0)
    {
        PrintFormat("Failed to get time. [%d]", GetLastError());
        return;
    }

    // 足確定
    if (dt != prevBarDt)
    {
        if (status > 0)
            CheckExit();
        else
            CheckEnter();

        prevBarDt = dt;
    }
}
//+------------------------------------------------------------------+
//| Trade function                                                   |
//+------------------------------------------------------------------+
void OnTrade()
{
    if (PositionsTotal() <= 0)
        status = 0;
}
//+------------------------------------------------------------------+